TV畸变宏编写

wsjch

之前在光学人生，论坛和光行天下，看到同一份资料@光杆司令 ，感谢分享。
尝试了两天将宏编写出来。
得到的数据基本一致，谢谢分享方法。我会在完善（加入图像显示）之后把宏分享给大家。
多多向论坛大佬学习！

Dreamor_007

我也想学习  宏编写···~   


如果可以 分享一下经验···

wsjch

Dreamor_007 发表于 2017-8-13 16:27
我也想学习  宏编写···~   

我就看了一下午Zemax中文手册中的zpl部分。没全部看完，只找需要的部分。如果你之前也对编程接触过，这个是很简单的东西，逻辑和方法搞清楚了，实现功能就只是熟悉下它的语法，然后写下来。
一起学习交流。

光杆司令

赞一个
很好奇你会加入什么图像

wsjch

光杆司令 发表于 2017-8-13 22:06
赞一个
很好奇你会加入什么图像

我想试试让运行宏就自己弹出畸变图像对比。之前看论坛手机镜头设计那个视频，里面运行的TV畸变宏好像有这么个功能。
还有个问题。评价函数里面框出来的那个计算，只是为了在Grid Distortion中设置那个0.75吧。后面的计算并不需要。

光杆司令

wsjch 发表于 2017-8-14 09:44
我想试试让运行宏就自己弹出畸变图像对比。之前看论坛手机镜头设计那个视频，里面运行的TV畸变宏好像有这 ...

是的，是专门为Grid Distortion计算的

wsjch

光杆司令 发表于 2017-8-14 09:55
是的，是专门为Grid Distortion计算的

再请教一下，为什么我加入中文永远是乱码，搞的我只能用英文写上去。

光杆司令

09版ZPL宏不能有中文字符，16版本可以
更新：应该是编码的问题，在09版里需要将编码设置为ASNI

numberw

碰巧有一个以前别人写的关于  TV畸变的宏，你可以参考一下，加了几个其他的考虑，比如默认长宽比4：3（1.3333），也可手动输入长宽比，我对宏也没什么了解只是个搬运工，希望这个对你有帮助，把这个宏改的更好，把下面的全部复制放在新zpl就可以直接用


!网格畸变计算宏,应该是搬的湾湾写的宏，原作者查不到了
!输入的宽高比例只是一个近似,近轴宽高和实际宽高都与之不完全相同.


!closewindow
!输入芯片比例数据
rate=0
INPUT "请设置芯片的宽高比例(H/V),默认为4/3=1.33333:", rate
if rate==0
  rate=1.33333
endif

format 10.4

!计算芯片比例
VR=SQRT(1/(1+rate*rate))
HR=RATE*VR

!获取最大视场
NFLD_=NFLD()
MXF=0
FOR I=1,NFLD_,1
  IF ABSO(FLDY(I))>MXF  THEN MXF=ABSO(FLDY(I))
NEXT

!获取表面数
N=NSUR()

!近轴追迹
PARAXIAL ON
RAYTRACE HR,VR,0,0,pwav()
Y_max=ABSO(RAGY(N))
X_max=ABSO(RAGX(N))
PARAXIAL OFF
!计算近轴的比例
prate=x_max/y_max

!画图
Graphics
gtitle "Grid Distortion"
xmx=xmax()
xmn=xmin()
ymx=ymax()
ymn=ymin()
xwidth=xmx-xmn
ywidth=ymx-ymn
!计算画图区域的高度与宽度
Vmm=0.6*ywidth
Hmm=prate*Vmm

!画出图框
xleft =xmn+(xwidth-Hmm)/2
xrigh =xmx-(xwidth-Hmm)/2
ytopp =ymn+(0.1*ywidth)
ybott =ymn+(0.7*ywidth)
x_center=xleft+(xrigh-xleft)/2
y_center=ytopp+(ybott-ytopp)/2
LINE xleft,ytopp,xrigh,ytopp
LINE xrigh,ytopp,xrigh,ybott
LINE xrigh,ybott,xleft,ybott
LINE xleft,ybott,xleft,ytopp

!画出格子(近轴像高网格)../20,按水平和垂直的近轴高度,内部按等比例画格子,近似近轴高度
incx=Hmm/20
incy=Vmm/20
for i=1,19,1
  line (xmn+(xwidth-Hmm)/2+incx*i),ymn+(0.7*ywidth),(xmn+(xwidth-Hmm)/2+incx*i),ymn+(0.1*ywidth)
  line (xmn+(xwidth-Hmm)/2),(ymn+(0.1*ywidth)+incy*i),(xmx-(xwidth-Hmm)/2),(ymn+(0.1*ywidth)+incy*i)
next

SETVECSIZE(500)
count=1
!计算实际像高
for ii =-1,1,0.1
  for jj=-1,1,0.1
    RAYTRACE ii*HR,jj*VR,0,0,pwav()
    rY_max=RAGY(N)
    rX_max=RAGX(N)
    VEC1(COUNT)=ry_max
    VEC2(COUNT)=rx_max
    count=count+1
  next
next

!画实际像高网格图
color 5
for i=1,count,21
oldx=x_center+vec2(i)*(Hmm/2)/x_max
oldy=y_center-vec1(i)*(Vmm/2)/y_max
  for j=1,20,1
  newx=x_center+vec2(i+j)*(Hmm/2)/x_max
  newy=y_center-vec1(i+j)*(Vmm/2)/y_max
  line oldx,oldy,newx,newy
  oldx=newx
  oldy=newy
  next
next

for i=1,21,1
oldx=x_center+vec2(i)*(Hmm/2)/x_max
oldy=y_center-vec1(i)*(Vmm/2)/y_max
  for j=21,count-21,21
  newx=x_center+vec2(i+j)*(Hmm/2)/x_max
  newy=y_center-vec1(i+j)*(Vmm/2)/y_max
  line oldx,oldy,newx,newy
  oldx=newx
  oldy=newy
  next
next

!注释
color 1
glensname
gdate
UNT=UNIT()
IF (UNT==0) THEN UNTS$="MILIMETERS"
IF (UNT==1) THEN UNTS$="CENTIMETERS"
IF (UNT==2) THEN UNTS$="INCHES"
IF (UNT==3) THEN UNTS$="METERS"
GTEXT XMN+0.02*XWIDTH,YMN+0.91*YWIDTH,0,"H:V(sen):"
GTEXT XMN+0.02*XWIDTH,YMN+0.945*YWIDTH,0,"IMAGE(P):"

GTEXT XMN+0.13*XWIDTH,YMN+0.91*YWIDTH,0,$str(HR)
GTEXT XMN+0.28*XWIDTH,YMN+0.91*YWIDTH,0,$str(VR)
GTEXT XMN+0.28*XWIDTH,YMN+0.91*YWIDTH,0,"W"
GTEXT XMN+0.43*XWIDTH,YMN+0.91*YWIDTH,0,"H"

GTEXT XMN+0.13*XWIDTH,YMN+0.945*YWIDTH,0,$str(X_MAX*2)
GTEXT XMN+0.28*XWIDTH,YMN+0.945*YWIDTH,0,$str(Y_MAX*2)
GTEXT XMN+0.28*XWIDTH,YMN+0.945*YWIDTH,0,"W"
GTEXT XMN+0.43*XWIDTH,YMN+0.945*YWIDTH,0,"H"

Ftp=FTYP()
if (Ftp == 0)
gtext xmn+0.47*xwidth,ymn+0.91*ywidth,0,"DEGREES"
else
gtext xmn+0.47*xwidth,ymn+0.91*ywidth,0,UNTS$
endif
gtext xmn+0.47*xwidth,ymn+0.945*ywidth,0,UNTS$

color 2
gtext x_center-xwidth*0.13-,ymn+0.75*ywidth,0,""

color 3
GTEXT xmx-(xwidth-Hmm)/2+0.03*xwidth,YMN+0.7*YWIDTH,90,"Caution: "
GTEXT xmx-(xwidth-Hmm)/2+0.06*xwidth,YMN+0.7*YWIDTH,90,"If Decenter or Title,The grid is "
GTEXT xmx-(xwidth-Hmm)/2+0.09*xwidth,YMN+0.7*YWIDTH,90,"right,But the date is wrong!"

!-----------------------------------------------------
!计算TV畸变
color 1
PARAXIAL OFF
RAYTRACE HR,VR,0,0
YC=RAGY(N)
XC=RAGX(N)

RAYTRACE HR,0,0,0
H=RAGX(N)
RAYTRACE 0,VR,0,0
V=RAGY(N)

TVH = (YC-V)/YC * 100
TVV = (XC-H)/XC * 100

gtext x_center-xwidth*0.18,ymn+0.05*ywidth,0,"TV Distortion(H)"
gtext x_center+xwidth*0.025,ymn+0.05*ywidth,0,$str(TVH)
gtext x_center+xwidth*0.175,ymn+0.05*ywidth,0,"%"
gtext x_center-(Hmm)/2-0.05*ywidth,ymn+0.64*ywidth,90,"TV Distortion(V)"
gtext x_center-(Hmm)/2-0.05*ywidth,ymn+0.37*ywidth,90,$str(TVV)
gtext x_center-(Hmm)/2-0.05*ywidth,ymn+0.17*ywidth,90,"%"

color 0
line 0.01*xwidth,0.035*ywidth,0.05*xwidth,0.035*ywidth
gtext 0.06*xwidth,0.035*ywidth,0,"paraxial"
color 5
line 0.01*xwidth,0.07*ywidth,0.05*xwidth,0.07*ywidth
gtext 0.06*xwidth,0.07*ywidth,0,"real"

Graphics off

format 5.3
print "   "
print "V / H Aspect:  ",1/RATE
print "   "
print "The vertical TV-DISTION IS(%):    ",tvv,"  %"
print "   "
print "The horizontal TV-DISTION IS(%):  ",tvh,"  %"
print "   "
print " "

wsjch

numberw 发表于 2017-8-14 21:43
碰巧有一个以前别人写的关于  TV畸变的宏，你可以参考一下，加了几个其他的考虑，比如默认长宽比4：3（1.33 ...

厉害了 我试试看 ，一对比我写的简直就是小学生