SYNOPSYS软件代码详解-消色差透镜设计及公差分析

asdoptics

消色差透镜设计及公差分析

参考Donald Dilworth《Lens Design Automatic and quasi-autonomous computational methods and techniques》书第十二、十三章

首先，消色差透镜的初始结构设计代码如下：
RLE                                                     ！读取镜头文件
ID F10 APO                                        ！镜头标识
WAVL 0.65 0.55 0.45                         ！定义三个波长，按照长波到短波顺序排列
APS 3           ！光阑面为表面3，程序会执行一个光瞳来重新计算YP1和XP1，而忽略输入的YP1和XP1值。
UNITS INCH                                      ！透镜单位为英寸

OBB 0 0.5 2 -0.01194 0 0 2     ！物体类型为OBB，0-入射边缘光线角度（针对无限远物），0.5-半视场角，2-半孔径，-0.01194-表面1上主光线高度，负号是指光线在图像下端；后面三个参数表示光线在X-Z平面的相应值

0 AIR                                                                        ！物面处于空气中
1 RAD -300.4494760791975   TH      0.58187611  ！表面1的半径，厚度
1 N1 1.60978880 N2 1.61494395 N3 1.62386887  ！玻璃类型为N-SK4的三个波长折射率被精确指定
1 GTB S    'N-SK4 '                                                  ！表面1玻璃类型为N-SK4
2 RAD     -7.4819193194388   TH      0.31629961 AIR   ！表面2在空气中的半径，厚度
2 AIR                                                                                 ！表面2处于空气中
3 RAD     -6.8555018049530   TH      0.26355283           ！表面3的半径，厚度
3 N1 1.60953772 N2 1.61628830 N3 1.62823445         ！玻璃类型为N-KZFS4的三个波长折射率被精确指出
3 GTB S    'N-KZFS4'                                                     ！表面3玻璃类型为N-KZFS4
4 RAD      5.5272935517214   TH      0.04305983 AIR    ！表面4在空气中的半径，厚度
4 AIR                                                                                  ！表面4处于空气中
5 RAD      5.6098999521052   TH      0.53300999   ！表面5的半径，厚度
5 N1 1.66610392 N2 1.67304720 N3 1.68543133   ！玻璃类型为N-BAF10的三个波长折射率被精确指出
5 GTB S    'N-BAF10'                                               ！表面5玻璃类型为N-BAF10
6 RAD    -27.9819596092866  TH     39.24611007 AIR   ！表面6在空气中的半径，厚度
6 AIR                                                                                  ！表面6处于空气中
6 CV      -0.03573731                                                         ！表面6的曲率

6 UMC -0.05000000       ！UMC求解表面6的曲率，并给出相对于光轴的近轴轴向边缘光线角U的规定值。U的正切值为1/(2*FNUM)=0.05,负号表示边缘光线在图像下端。

6 TH     39.24611007      ！表面6的厚度
6 YMT 0.0000000          ！YMT求解在表面7上指定的轴向边缘光线高度为0时所对应的厚度
7 RAD    -11.2104527948015   TH      0.00000000 AIR  ！表面7（像面）的半径，厚度
END                                                                                  ！以END结束


运行上述代码后，点击图标 打开PAD二维图，得到消色差透镜的初始结构，如图1所示：

图1 消色差透镜的初始设计

点击PAD图中的图标，打开玻璃表，已经选中玻璃库Schott，这是我们先前指定的玻璃库，点击OK，得到显示Nd和Vd的玻璃图，如下图：

绿色圆圈旁边的数字表示目前三片式透镜表面1、表面3、表面5，即被定义了玻璃类型的表面。
而我们关心的是色散特性。所以需单击‘Graph’按钮，然后单击‘Plot P(F,e)vs.Ve’，再点击‘OK’。

得到玻璃的色散图如下：

现在，我们查看表面1的玻璃材料的性能。具体操作：单击数字1的绿色圆圈，然后单击‘Properties’按钮。最后表面1的玻璃材料N-SK4的性能如下：

图中显示，N-SK4的酸度(Acid)等级为5，湿度等级(Humidity)为3;此玻璃暴露在空气中的性能不稳定。因此，需要更换一种玻璃材料。
如何选取更换材料？首先我们单击'Graph'按钮，选择‘Acid Sensitivity ’,点击‘OK’，得到下图，图中玻璃位置处的红色垂线表示酸敏感度，垂线越长，玻璃越不耐用。

从图中，我们发现N-BAK2根本没有线，可以选取其作为更换材料。

于是，单击N-BAK2符号，名称出现在右侧窗口时，在‘Surface’中填写‘1’，然后点击'Apply',这样就为表面1分配了玻璃类型N-BAK2。

另外，N-BAK2的特性如下，其酸碱度等级为1，湿度等级为2，而且价格也比N-SK4低：

现在PAD图中的透镜像差非常差，这是因为表面1更换玻璃N-BAK2后，还未进行优化，如图2所示：

图2更换玻璃N-BAK2后的消色差透镜

接下来，运行下面代码对透镜进行优化，代码如下：
PANT                                            ！参数输入
VLIST RAD 1 2 3 4 5 7                ！改变表面1、表面2、表面3、表面4、表面5以及表面7的半径
VLIST TH 2 4                               ！改变表面2和表面4的厚度
END                                              ！以END结束

AANT                                           ！像差输入
AEC                                              ！自动控制玻璃元件和空气间隙的边缘羽化，防止边缘厚度太薄
ACC                                              ！自动控制玻璃元件的中心厚度，防止中心厚度太厚
GSO 0 1 4 M 0 0  ！校正0视场弧矢面中产生的光线网格OPD像差；0-孔径权重占比，1-权重，4-光线数，M-多色，0-Y视场，0-X视场；
GNO 0 .2 3 M .75 0  ！校正0.75视场光线网格OPD像差
GNO 0 .1 3 M 1.0 0  ！校正全视场光线网格OPD像差
END                          ！以END结束

SNAP                        ！设置PAD更新频率，每迭代一次PAD更新一次
SYNO 30                  ！迭代次数30次
优化后的消色差镜头结构，如图3所示。由图可知，此透镜的校正的光程差优于1/4波长。并保存镜头文件，命名为'C12L2.RLE'。

图3 通光更换玻璃后重新优化的消色差透镜

接着，我们查看离焦在新设计中随波长的变化，如下图。运行以下代码：
CHG                    ！改变镜头
NOP                     ！移除所有在透镜上的拾取和求解
END                     ！以END结束
PLOT DELF FOR WAVL = .45 TO .65  ！绘制离焦在波长0.45um~0.65um范围内的变化

离焦随波长变化的数据分析，分析表明在设计波长范围内的离焦大约为0.0026英寸。

透镜具有完美的艾里斑，通过图像工具(MIT)计算，并且为透镜分配了十个波长，在中心产生良好的白色，并具体相干效果。如下图。

现在，我们计算消色差透镜的公差。首先移除表面6上的曲率求解。代码如下：
CHG
6 NCOP          ！移除表面6的曲率求解
END

然后，在CW命令窗口输入MSB，进行BTOL设置，如图：

其中，数字2-设置统计可信水平为2个sigma，则在一大批透镜中应有99.53%透镜的像质等于或优于要求。
在CW中看到预期的结果如下图。图中表明轴上像质将会有0.05的变动。

预测的公差如图所示。由图可知，透镜1和透镜2之间的空气间隔公差为0.00157英寸。透镜2和透镜3之间的空气间隔公差为0.000426英寸。
透镜2的V-number的公差为0.05359。同时该透镜保持0.00024的共轴性。

现在呢，公差太小，没有办法按照预估公差来制造透镜。所以怎样将公差放大呢？
在CW中输入THIRD SENS：

SAT的值为8.363，即每个表面对球差SA3贡献的平方和为8.363。接下来，通光减小SAT值，来降低公差灵敏度，放大公差。

优化宏代码如下：
PANT
VLIST RAD 1 2 3 4 5 7
VLIST TH 2 4
END
AANT
AEC
ACC
M 4 1 A SAT                      ！SAT的目标值为4，权重为1；
GSO 0 1 5 M 0 0  
GNO 0 .2 4 M .75 0  
GNO 0 .1 4 M 1.0 0  
END
SNAP
SYNO 30


优化后的透镜结果，如图4所示：

图4 减小SAT值，优化后的消色差透镜

现在的THIRD SENS为：

接下来，我们通过编辑BTOL宏来计算公差。

新BTOL宏代码如下：
CHG
NOP
END

BTOL 2                      ！设置置信区间

EXACT INDEX 1 3 5    ！表面1，表面3和表面5的折射率是精确的
EXACT VNO 1 3 5        ！表面1，表面3和表面5的V-number是精确的

TPR ALL                  ！  假定所有表面与光学样板匹配                                                            
TOL WAVE 0.1        ！最大波前变化值为0.1
ADJUST 6 TH 100 100  ！调整表面6的厚度，第一个数字100是指一组移动的表面数目；第二个
                                             数字100是指允许的最大调整值；

PREPARE MC         ！自动准备一个调整文件，以便后续的MC运行需使用该文件来检查统计信息

GO                          ！BTOL输入文件的最后输入，并执行程序
STORE 4                ！透镜结果储存在透镜库的位置4
运行BTOL宏之后，公差稍微宽松一点，如下图：

接着，运行MC程序来检查透镜情况。在CW中输入：SYNOPSYS AI> MC 50 4 QUIET -1 ALL 5;此命令将会测试一批储存在透镜库4中的50片透镜，按照上述预计公差来制作透镜，然后监控比较这一批透镜的统计数据，将最坏的透镜情况保存在透镜库位置5。

在CW窗口输入：MC PLOT，得到MC直方图：

现在测试最坏的透镜。点击  ，在CW中输入GET 5，即将MC最坏的透镜放在ACON2中,如图5所示。

图5 MC最差透镜情况。必须制造调整。

于是，对保存在透镜库4的透镜进行制造调整。使用FAMC指令(FAMC是制造调整MC)分析统计数据。代码如下：
FAMC 50 4 QUIET -1 ALL 5  ！测试透镜库4中的50片透镜，按照预计公差来制作透镜，然后监控对比所有透镜质量，将最坏透镜结果保存在透镜库5
PASSES 20           ！对第一阶段(PHASE 1)优化的迭代次数
FAORDER 5 3 1  ！透镜制造序列，按难度排序，最复杂的透镜放首位

PHASE 1              ！第一阶段，优化透镜参数
PANT
VLIST RAD 1 2 3 4 5 6
VLIST TH 2 4 6
END

AANT
GSO 0 1 5 M 0
GNO 0 1 5 M 1  
END
SNAP
EVAL   ！必须以EAVL结束，第一阶段已经将透镜公差应用于透镜本身，然后依次完成所有透镜制作

PHASE 2              ！第二阶段，只优化不包括在第一阶段中的透镜参数和评价函数
PANT
VY 3 YDC 2 100 -100   ！改变表面3的Y方向偏心，上限为2，下限为100，增量为-100
VY 3 XDC 2 100 -100   ！改变表面3的X方向偏心
VY 5 YDC 2 100 -100
VY 5 XDC 2 100 -100
VY 6 TH                        ！改变表面6的厚度
END
AANT
GNO 0 1 4 M 0 0 0 F
GNO 0 1 4 M 1 0 0 F  
END
SNAP
SYNO 30

PHASE 3 ！第三阶段；当遇到第三阶段的输入，程序循环整个过程

运行代码之后，得到带有制造调整的MC的最差透镜情况，如图6所示。

图6 带有制造调整的MC最差透镜情况。

再次在CW中输入MC PLOT，得到MC直方图：

相应的局部放大轴上视场直方图

打开MPL对话框设置后，透镜元件2的ELD绘制出图：

打开MPL对话框设置后，点击DWG得到透镜装配图，图中添加了空气间隙，倾斜角，还有偏心公差：